ABAP中的枚举对象

 

枚举对象是枚举类型的多寡对象。枚举对象只可以分包类型为枚举类型的枚举值。ABAP从版本7.51开始协理它们。

那是风流倜傥种家常便饭的方式。在ABAP 7.51事先,大家日常用如下情势完结相近的功能:

CLASS cx_wrong_size DEFINITION INHERITING FROM cx_static_check.
 ENDCLASS.

 CLASS shirt DEFINITION.
   PUBLIC SECTION.
     TYPES tsize TYPE i.
     CONSTANTS:
       size_s  TYPE tsize VALUE 0,
       size_m  TYPE tsize VALUE 1,
       size_l  TYPE tsize VALUE 2,
       size_xl TYPE tsize VALUE 3.
     METHODS
       constructor IMPORTING size TYPE tsize
                   RAISING   cx_wrong_size.
     ...
   PRIVATE SECTION.
     DATA
       size TYPE tsize.
 ENDCLASS.

 CLASS shirt IMPLEMENTATION.
   METHOD constructor.
     IF size <> size_s AND
        size <> size_m AND
        size <> size_l AND
        size <> size_xl.
       RAISE EXCEPTION TYPE cx_wrong_size.
     ENDIF.
     me->size = COND #(
       WHEN size <> size_s AND
                    size <> size_m AND
                    size <> size_l AND
                    size <> size_xl THEN THROW cx_wrong_size( )
       ELSE size ).
   ENDMETHOD.
 ENDCLASS.

此间,size属性只好够是shirt类中定义的常量中的值。此外值会招致万分。客商成立shirt类时,需求那样做:

TRY.
    DATA(shirt) = NEW shirt( shirt=>size_xl ).
  CATCH cx_wrong_size.
    ...
ENDTRY.

观望花销了啊?为啥不让运维时碰着来为您做值检查吧?有意气风发种名字为枚举和枚举类型的定义(能够在这里种状态下使用卡塔尔。

在7.51以至越来越高的本子里,ABAP也会帮助枚举概念。如若利用枚举类型来重写下面的例证的话:

CLASS shirt DEFINITION.
  PUBLIC SECTION.
    TYPES:
      BEGIN OF ENUM tsize,
        size_s,
        size_m,
        size_l,
        size_xl,
      END OF ENUM tsize.
    METHODS
      constructor IMPORTING size TYPE tsize.
    ...
  PRIVATE SECTION.
    DATA
      size TYPE tsize.
ENDCLASS.

CLASS shirt IMPLEMENTATION.
  METHOD constructor.
    me->size = size.
  ENDMETHOD.
ENDCLASS.

TYPES语句的多个新变式:BEGIN OF ENUM大红鹰葡京会,END OF
ENUM
,它能够围起多少个常量的集。常量的正式基本类型是i相同的时间枚举值从0开端计数。

像上文那样选择的话:

DATA(shirt) = NEW shirt( shirt=>size_xl ).

只是,使用了枚举对象后,你不再必要管理特别了。若是您传递多少个违规值的话,会获得语法错误!

DATA(shirt) = NEW shirt( 333 ).

大红鹰葡京会 1

 

枚举是项目和常量的混合体。通过BEGIN OF ENUM enum – END OF ENUM
enum

你证明了叁个方可在TYPE附加项后宣称的主导项目enum。在它们中间,你能够声美素佳儿(Friso卡塔尔个常量集,它们叫做枚举常量。那样就定义了具有enum品类的枚举对象所允许的枚举值。在这里间,TYPES骨子里就和CONSTANTS话语同样。

ABAP运营时情况会检查唯有被允许的枚举值能够被赋给枚举对象。

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA size TYPE tsize.
size = size_xl. "允许

DATA dobj LIKE size.
dobj = size. "允许

dobj = 333. "语法或运行时错误

枚举对象只可以赋值给具备相近枚举类型的枚举对象。雷同,枚举对象间的相比较也只幸好同等类别的枚举对象间产生。当然,枚举常量本身也隐含在内。

不乏先例,你或多或少也不关注枚举对象的故事情节。枚举对象的语义由枚举常量来定义。但是,你也能够将枚举类型定义为i类型之外的其他基本类型,而且具有别样枚举值(当中一个必需是伊始值卡塔 尔(阿拉伯语:قطر‎:

TYPES:
  basetype TYPE c LENGTH 2,
  BEGIN OF ENUM tsize BASE TYPE basetype,
    size_i  VALUE IS INITIAL,
    size_s  VALUE `S`,
    size_m  VALUE `M`,
    size_l  VALUE `L`,
    size_xl VALUE `XL`,
  END OF ENUM tsize.

DATA size TYPE tsize.
size = size_xl. "允许

DATA dobj LIKE size.
dobj = size."允许

那令你可以轻巧地把现成“枚举值”转变为新章程的枚举值。运气好的话,能够无需调治它们的施用。

设若您在一个上下文中有超过常规贰个枚举类型,你能够将依次枚举值协会到组织里:

TYPES:
  BEGIN OF ENUM tsize STRUCTURE size,
    s,
    m,
    l,
    xl,
  END OF ENUM tsize STRUCTURE size.

DATA dobj TYPE tsize.
dobj = size-xl. "允许

上述代码定义了三个枚举结构size。结构的构件是枚举类型的枚举常量。

 

枚举对象的周围用项是相比它和枚举常量以决定程序必要切换成哪叁个效果与利益分支:

TYPES:
  BEGIN OF ENUM tsize STRUCTURE size,
    s,
    m,
    l,
    xl,
  END OF ENUM tsize STRUCTURE size.

DATA dobj TYPE tsize.

...

CASE dobj.
  WHEN size-s.
    ...
  WHEN size-m.
    ...
  WHEN size-l.
    ...
  WHEN size-xl.
    ...
ENDCASE.

 除此而外,还应该有部分方可使用的情况:

你能够将枚举对象赋给三个c项目或然string品类的文书。结果正是概念了枚举值的枚举常量的名字。

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA text TYPE string.
text = size_xl.
cl_demo_output=>display( text ). "结果是SIZE_XL

也得以编写:

DATA(text) = CONV string( size_xl ).

能够动用CONV操作符钦赐项目来访问当前值:

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(value) = CONV i( size_xl ) .
cl_demo_output=>display( value ). "输出结果是3

另黄金时代种方式是,能够选择CONV将贰个卓有功用的枚举值调换为枚举对象(常规的赋值语句是回天无力完结的卡塔尔国:

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(num) = 3.

TRY.
    DATA(dobj) = CONV tsize( num ) .
    cl_demo_output=>display( dobj ). "Output is SIZE_XL
  CATCH cx_sy_conversion_no_enum_value.
    ...
ENDTRY.

RTTI中也多了一个相应的类CL_ABAP_ENUMDESCR

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(size) = VALUE tsize( ).

DATA(enum_descr) = CAST cl_abap_enumdescr(
  cl_abap_typedescr=>describe_by_data( size ) ).

cl_demo_output=>new(
  )->write_data( enum_descr->kind            "E, for elementary
  )->write_data( enum_descr->type_kind       "k, new for enumerated type
  )->write_data( enum_descr->base_type_kind  "I, the base type
  )->write_data( enum_descr->members         "Table of constants and values
  )->display( ).

繁多就是那些剧情了。

躺下让ABAP运维时来为你办事呢。要留意枚举类型只好在好几符合的演算地点中现身,並且只好分包预先规定的值。违规的枚举值永久不会在枚举对象中冒出。

 

PS:原来的书文的褒贬中有人涉嫌,枚举值和数码字典中的domain的固定值很像,为啥双方未有并轨关系?

小编的答疑是:这一个脾性实际仲春经在筹算中了,很有期望现身。具体意况要视能源和事先级而定。

 

正文链接:http://www.cnblogs.com/hhelibeb/p/7976078.html

希伯来语原稿:ABAP News for Release 7.51 –
Enumerations

 

相关文章

admin

网站地图xml地图